Penerapan Enum pada Visual Basic .Net framework

​

Enum digunakan untuk menyimpan konstan value yang digunakan dalam program. Mari kita gunakan Select-Case dan juga IF-Else dalam penerapannya.

CODE-1

Code:

Module Module1

    ''' <summary>
    ''' Levels of importance.
    ''' </summary>
    Enum Importance
        None = 0
        Trivial = 1
        Regular = 2
        Important = 3
        Critical = 4
    End Enum

    Sub Main()
        Dim value As Importance = Importance.Critical
        ' Select the enum and print a value.
        Select Case value
            Case Importance.Trivial
                Console.WriteLine("Not true")
                Return
            Case Importance.Critical
                Console.WriteLine("True")
                Exit Select
        End Select
    End Sub

End Module

Lihatlah disini bagian yang memeriksa beberapa nilai Enum dengan beberapa kondisi tertentu. Sebuah variable Dim dicheck dengan kontan value dari Enum.

Contohnya kita menggunakan HTML markup, lalu dalam konsepnya kita terapkan pada Enum. Kemudian kita periksa bagian tags tertentu dengan IF-ELSE statement.

CODE-2

Code:

Module Module1

    ''' <summary>
    ''' Represents tag type.
    ''' </summary>
    Enum TagType
        None = 0
        BoldTag = 1
        ItalicsTag = 2
        HyperlinkTag = 3
    End Enum

    Sub Main()
        ' Create enum type variable.
        Dim value As TagType = TagType.HyperlinkTag
        ' Use enum in If-statement.
        ' ... Also use ElseIf statement.
        If value = TagType.BoldTag Then
            Console.WriteLine("Bold")
        ElseIf value = TagType.HyperlinkTag Then
            Console.WriteLine("Not true")
        End If
    End Sub

End Module

Kali ini Enum dengan menggunakan ToString. Ketika kita ingin menerapkan nilai String, maka pada sebuah Enum harus disertakan ToString agar dapat digunakan pada Write ataupun WriteLine sub. Hal ini dikarenakan jika tidak menggunakan ToString maka nilai yg kita dapat hanyalah angka (numeric value) dan bukan itu yg kita inginkan. Dalam contoh dibawah ini kita menggunakan ToString pada sebuah Enum bernama AnimalType.

CODE-3

Code:

Module Module1

    ''' <summary>
    ''' Type of animal.
    ''' </summary>
    Enum AnimalType
        None = 0
        Cat = 1
        Dog = 2
    End Enum

    ''' <summary>
    ''' Type of visibility.
    ''' </summary>
    Enum VisibilityType
        None = 0
        Hidden = 2
        Visible = 4
    End Enum

    Sub Main()
        Dim dog As AnimalType = AnimalType.Dog
        Dim hidden As VisibilityType = VisibilityType.Hidden
        ' Write to the Console with the ToString method.
        Console.WriteLine(dog.ToString)
        Console.WriteLine(hidden.ToString)
    End Sub

End Module

Stack. Kapan digunakannya? Ketika kita memiliki HTML Doc dengan tags, maka sebuah Enum ataupun Stack boleh dipakai disini. Bisa juga digunakan ketika ingin menerapkan validitas Opening & Closing tags matching. Stack ini berupa Collection, maka yang dipakai ialah Push, Pop, dan Peek method.

CODE-4

Code:

Module Module1

    Enum TagType
        None = 0
        BoldTag = 1
        ItalicsTag = 2
        HyperlinkTag = 3
    End Enum

    Sub Main()
        ' Create a new Stack generic instance.
        Dim stack As New Stack(Of TagType)
        ' Add a BoldTag to it.
        stack.Push(TagType.BoldTag)
        ' Add an ItalicsTag to it.
        stack.Push(TagType.ItalicsTag)
        ' Pop the top element.
        ' ... Then write it to the Console.
        Dim popped As TagType = stack.Pop()
        Console.WriteLine(popped)
        Console.WriteLine(popped.ToString)
    End Sub

End Module

Default. Pada sebuah Enum tertulis dipernyataan awalnya yang bernilai 0. Sehingga jika diurutkan nilainya bermula dari 0, 1, 2, dan seterusnya. Jika sebuah Enum digunakan pada bagian suatu Class tertentu, maka kita tidak perlu memberikan nilai sesuatu padanya. Biarkan saja default value yg akan didapat secara otomatis.

CODE-5

Code:

Module Module1

    Enum Level
        Normal
        Low
        High
    End Enum

    Class Item
        ''' <summary>
        ''' Public enum.
        ''' </summary>
        Public _level As Level
    End Class

    Sub Main()
        ' The default value for an enum is the one equal to 0.
        Dim v As Item = New Item
        Console.WriteLine(v._level.ToString())
    End Sub

End Module

Types. Dalam Enum ia dapat diberikan pula sebuah data Type. Seperti integer, Byte, dan lainnya. Contohnya kali ini kita terapkan beberapa Byte pada Enum. Hal ini berguna ketika sebuah Class sering di-inisialisasi dalam memory. Dan dengan ini pula sebenarnya kita menghemat penggunaan memory berlebih. Empat buat Bytes biasanya menjadi 1 buah Integer.

CODE-6

Code:

Module Module1

    Enum Code As Byte
        Small = 0
        Medium = 1
        Large = 2
    End Enum

    Sub Main()
        ' The value is represented in a byte.
        Dim value As Code = Code.Medium
        Console.WriteLine(value)
    End Sub

End Module

Nilai lain. Dalam VB.net sebuah Enum sebenarnya dapat pula menggunakan nilai lain yang tidak berasal dari Enum itu sendiri. Tidak akan ada error, warning, ataupun crash lainnya. Coba perhatikan contoh dibawah.

CODE-7

Code:

Module Module1

    Enum PageColor
        None = 0
        Red = 1
        Blue = 2
        Green = 3
    End Enum

    Sub Main()

        ' This value does not exist in the enum type.
        Dim value As PageColor = 4

        ' We can still test an enum against any value.
        If value = 4 Then
            Console.WriteLine("Value is 4")
        End If
    End Sub

End Module

Adapun Parse. Dalam penerapan Enum akan dibahas pada artikel yang berlainan. Enum sangat penting untuk dipakai. Terutama ketika ingin menerapkan beberapa konstan tertentu. Dengan beberapa symbolic constant seperti ini maka penerapan dalam variable menjadi lebih mudah.

RUJUKAN ASLI



Jika dirasa bermanfa'at please click Like.
Tp klo ada yg kurang, smoga kita bisa diskusi, PM ya. Nnti boleh koq ktmuan.